54 lines
1.6 KiB
Batchfile
54 lines
1.6 KiB
Batchfile
@echo off
|
|
setlocal
|
|
|
|
:: Get current date in YYYY-MM-DD format
|
|
for /f "tokens=2-4 delims=/ " %%a in ('date /t') do (
|
|
set mm=%%a
|
|
set dd=%%b
|
|
set yy=%%c
|
|
)
|
|
set yyyy=20%yy:~-2%
|
|
|
|
:: Ask for project name
|
|
set /p projectName="Enter project name (press Enter for default 'NewProject'): "
|
|
if "%projectName%"=="" set projectName=NewProject
|
|
set projectRoot=%yyyy%-%mm%-%dd%_%projectName%
|
|
|
|
:: Create main project directory
|
|
mkdir "%projectRoot%"
|
|
|
|
mkdir "%projectRoot%\Assets\VO"
|
|
if exist "%~dp0NewDaily.bat" copy /Y "%~dp0NewDaily.bat" "%projectRoot%\Assets\VO\NewDaily.bat" >nul
|
|
|
|
:: Create Blends structure
|
|
mkdir "%projectRoot%\Blends\animations\"
|
|
mkdir "%projectRoot%\Blends\stills\img-BG"
|
|
|
|
:: Create Deliverable structure
|
|
mkdir "%projectRoot%\Deliverable\"
|
|
|
|
:: Create Pr structure
|
|
mkdir "%projectRoot%\Pr\RnR\RIFE"
|
|
|
|
:: Add project root additions
|
|
if not exist "%projectRoot%\Renders" mkdir "%projectRoot%\Renders"
|
|
|
|
:: Place helper scripts into Renders
|
|
if exist "%~dp0NewDaily.bat" copy /Y "%~dp0NewDaily.bat" "%projectRoot%\Renders\NewDaily.bat" >nul
|
|
if exist "%~dp0UpdateSequences.bat" copy /Y "%~dp0UpdateSequences.bat" "%projectRoot%\Renders\UpdateSequences.bat" >nul
|
|
|
|
:: Use repo-provided templates for git config files
|
|
if exist "%~dp0components\gitignore" copy /Y "%~dp0components\gitignore" "%projectRoot%\.gitignore" >nul
|
|
if exist "%~dp0components\gitattributes" copy /Y "%~dp0components\gitattributes" "%projectRoot%\.gitattributes" >nul
|
|
|
|
:: Initialize git and install Git LFS
|
|
pushd "%projectRoot%" >nul
|
|
git init
|
|
git lfs install
|
|
git add . -v
|
|
git commit -m "init"
|
|
popd >nul
|
|
|
|
echo Project structure created successfully in folder: %projectRoot%
|
|
pause
|