ProjectStructure_HOME/NewProject.bat

@echo off
setlocal

:: Get current date in YYMMDD format
for /f "tokens=2-4 delims=/ " %%a in ('date /t') do (
    set mm=%%a
    set dd=%%b
    set yy=%%c
)
set yy=%yy:~-2%

:: Ask for project name
set /p projectName="Enter project name (press Enter for default 'NewProject'): "
if "%projectName%"=="" set projectName=NewProject
set projectRoot=%yy%%mm%%dd%_%projectName%

:: Create main project directory
mkdir "%projectRoot%"

:: Create Assets structure
mkdir "%projectRoot%\Assets\ElevenLabs"
mkdir "%projectRoot%\Assets\Blends"
mkdir "%projectRoot%\Assets\VO"


:: Create Blends structure
mkdir "%projectRoot%\Blends\animations\_CURRENT"
mkdir "%projectRoot%\Blends\stills\_CURRENT"
mkdir "%projectRoot%\Blends\stills\img-BG"

:: Create Deliverable structure
mkdir "%projectRoot%\Deliverable\"

:: Create Pr structure
mkdir "%projectRoot%\Pr\RnR\RIFE"

:: Create Reference structure
mkdir "%projectRoot%\Reference\Translation Scripts"
mkdir "%projectRoot%\Reference\VO clips"

:: Add project root additions
if not exist "%projectRoot%\Renders" mkdir "%projectRoot%\Renders"

:: Place helper scripts into Renders
if exist "A:\1 Amazon_Active_Projects\3 ProjectStructure\NewDaily.bat" copy /Y "A:\1 Amazon_Active_Projects\3 ProjectStructure\NewDaily.bat" "%projectRoot%\Renders\NewDaily.bat" >nul
if exist "A:\1 Amazon_Active_Projects\3 ProjectStructure\UpdateSequences.bat" copy /Y "A:\1 Amazon_Active_Projects\3 ProjectStructure\UpdateSequences.bat" "%projectRoot%\Renders\UpdateSequences.bat" >nul

:: Create Translations Google Drive shortcut
echo [InternetShortcut] > "%projectRoot%\Reference\Translation Scripts\Translations Google Drive.url"
echo URL=https://drive.google.com/drive/folders/1lND5207vl-qf5RbTQ2eejeXJCc4r5rUo >> "%projectRoot%\Reference\Translation Scripts\Translations Google Drive.url"

:: Create Amazon folder shortcut
powershell -Command "$folder='%projectRoot%\Deliverable'; $WS = New-Object -ComObject WScript.Shell; $SC = $WS.CreateShortcut([System.IO.Path]::Combine($folder, 'Amazon - for Elizabeth.lnk')); $SC.TargetPath = 'D:\Amazon - for Elizabeth'; $SC.WorkingDirectory = 'D:\Amazon - for Elizabeth'; $SC.IconLocation = 'shell32.dll,3'; $SC.Save()"

:: Use repo-provided templates for git config files
if exist "A:\1 Amazon_Active_Projects\3 ProjectStructure\components\gitignore" copy /Y "A:\1 Amazon_Active_Projects\3 ProjectStructure\components\gitignore" "%projectRoot%\.gitignore" >nul
if exist "A:\1 Amazon_Active_Projects\3 ProjectStructure\components\gitattributes" copy /Y "A:\1 Amazon_Active_Projects\3 ProjectStructure\components\gitattributes" "%projectRoot%\.gitattributes" >nul

:: Initialize git and install Git LFS
pushd "%projectRoot%" >nul
git init
git lfs install
popd >nul

echo Project structure created successfully in folder: %projectRoot%
pause